- Auslisten aller im Projekt definierten Funktionen

- Suche nach toten Funktionen im Projekt
- Doppelklick auf Funktion öffnet die Datei mit der Deklaration

PKGBUILD-git

@@ -0,0 +1,43 @@
+# Maintainer: Dany Thinnes <dany@projekt-hirnfrei.de>
+# Projekt Hirnfrei - https://www.projekt-hirnfrei.de
+
+pkgname=barecode-git
+pkgver=1.1.0.r0.g0000000
+pkgrel=1
+pkgdesc="Schlanker modularer Code-Editor für HTML, PHP, CSS und C++ (Git-Version)"
+arch=('x86_64' 'aarch64')
+url="https://www.projekt-hirnfrei.de"
+license=('MIT')
+depends=('qt6-base')
+makedepends=('cmake' 'ninja' 'git')
+provides=('barecode')
+conflicts=('barecode')
+source=("$pkgname::git+https://git.projekt-hirnfrei.de/diabolus/BareCode.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags 2>/dev/null \
+        | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' \
+        || printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "$pkgname"
+    cmake -B build \
+        -G Ninja \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_SKIP_RPATH=ON
+    cmake --build build
+}
+
+check() {
+    :
+}
+
+package() {
+    cd "$pkgname"
+    DESTDIR="$pkgdir" cmake --install build
+    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}